くれびの窪み

'wscc.vbs:実文字数カウントスクリプト(for WSH)
'半角・全角スペース、タブ、改行を除いた文字数をカウント
'Ver1.0 2006/06/03 Kurebi
set args = wscript.arguments
if args.count = 0 then wscript.quit
set fso = createobject("scripting.filesystemobject")
set ts = fso.opentextfile(args(0))
b = 0
c = 0
do while not ts.atendofstream
    c1 = ts.read(1)
    select case c1
    case " ","　",vbtab,vbcr,vblf
    case else
        if asc(c1) >= 0 and asc(c1) <= &hff then
            b = b + 1
        else
            b = b + 2
        end if
        c = c + 1
     end select
loop
ts.close
set ws = wscript.createobject("wscript.shell")
n = ws.popup(b & "バイト (" & c & "文字)",0,"実文字数カウント",64)

1. 点線の中身を適当なファイル名（例：wscc.vbs）で保存します。
2. エディタにてスクリプトを起動する設定を行います。さらに対象のファイル名がパラメタとして渡るようにしてください。
   （仮にスクリプトファイルパスが"c:\wscc.vbs"として、例えば）
   • MKEditorの場合、コマンドにコマンドライン"c:\wscc.vbs"、パラメータ"%FILENAME%"として登録します。
   • EmEditor Free/Standardの場合、外部ツールにコマンド"c:\wscc.vbs"、引数"$(Path)"として登録します。
   • TeraPadの場合、ツールに実行ファイル"c:\wscc.vbs"、コマンドラインパラメータ"%f"として登録します。
3. エディタにて対象ファイルを表示した状態でスクリプトを実行すると、実文字のバイト数と文字数が表示されます。（実行する前に必ずファイルを保存してください）

• 表示されるバイト数は実文字の総バイト数（半角1バイト、全角2バイト）で、文字数は半角・全角を問わない全文字数です。（注：Unicode、EUC等シフトJIS以外のファイルでは正しく表示されません）
• 動作確認はWindows XP Home Edition(WSH5.6)で行いました。